GOM引擎材料跨区储存脚本

[@main]
#IF
CheckContainsText <$SERVERNAME> 测试
#ACT
MESSAGEBOX \测试区禁止使用.
BREAK

#IF
#ACT
Mov S81
Mov S82
Mov S83
Mov S84
Mov S85
Mov S86
Mov S87
OPENMERCHANTBIGDLG 55 20 1 4 40 -40 1 426 20
#SAY
\ \ \
< >           <欢迎来到《奉行网络银行》，很高兴为您服务！/FCOLOR=151>\ \
< >    <防止洗号，被盗号，可以把多余的四象之力存入银(任何区都可使用)/FCOLOR=154>\
< >    <凭独立账号密码,跨区存取四象之力（与角色账号无关）相当于转区！/FCOLOR=154>\ \
< >  <重要提示：请牢记设置的用户名、密码、二级密保，不要设置过于简单！/FCOLOR=249>\ \
< >  <重要提示：您所设置的银行账户所有区都可以登录，不要设置过于简单！/FCOLOR=250>\ \
<>               <登录银行系统/@登录银行>             <注册银行账户/@注册银行> \




;===========================注册银行账户===========================


[@注册银行]
#IF
#ACT
OPENMERCHANTBIGDLG 55 20 1 4 40 -40 1 426 20


#SAY
\ \ \
<>                 <银行账号：/FCOLOR=243> <$STR(S83)>  <请输入银行账号/@@InPutString83>\ \
<>                 <银行密码：/FCOLOR=243> <$STR(S84)>  <请输入银行密码/@@InPutString84>\ \
<>                 <确认密码：/FCOLOR=243> <$STR(S85)>  <请输入确认密码/@@InPutString85>\ \
<>                 <二级密保：/FCOLOR=243> <$STR(S86)>  <请输入二级密保/@@InPutString86>\  \
<>                                <确认开户|253#为防止小号注册加重服务器数据负担，^ ^253#开户需要1元宝使用过程中无任何费用。/@确定创建>


[@确定创建]
#IF
EQUAL S83
#ACT
MESSAGEBOX [提示]：用户名不能为空
break


#IF
EQUAL S84
#ACT
MESSAGEBOX [提示]：登录密码不能为空
break


#IF
EQUAL S85
#ACT
MESSAGEBOX [提示]：登录密码不能为空
break


#IF
EQUAL S86
#ACT
MESSAGEBOX [提示]：二级密码不能为空
break


#IF
CHECKGameGold > 1
#ELSEACT
MESSAGEBOX [提示]：您没有1个元宝，无法开户。
break


#IF
NOT EQUAL S83
NOT EQUAL S84
NOT EQUAL S85
NOT EQUAL S86
EQUAL N$是否注册 0
#ACT
GameGold - 1
MOV N$是否注册 1
Createfile ..\..\..\..\天魔银行\银行账号\<$STR(S83)>.txt
Createfile ..\..\..\..\天魔银行\银行密保\<$STR(S83)>.txt
AddTextListEx ..\..\..\..\天魔银行\账号密码.txt 账号<$STR(S83)>:密码<$STR(S84)> 0
AddTextListEx ..\..\..\..\天魔银行\账号密保.txt 账号<$STR(S83)>:密保<$STR(S86)> 0
AddTextListEX ..\..\..\..\天魔银行\银行密保\<$STR(S83)>.txt <$STR(S84)> 0
AddTextListEx ..\..\..\..\天魔银行\账号目录.txt <$STR(S83)> 0
AddTextListEx ..\..\..\..\天魔银行\开户记录.txt 开户时间：<$DATETIME>‖区名：<$SERVERNAME>‖帐号：<$USERID>‖角色：<$USERNAME>‖卡号：<$STR(S83)> 0
Messagebox [提示]：您的银行账户开户成功，请牢记您的资料：\　\登录账号：<$STR(S83)>\　\登录密码：<$STR(S84)>\　\二级密保：<$STR(S86)>
CLOSE
break


[@InPutString83]
#OR
CheckStringlength <$STR(S83)> < 1
CheckContainsText <$STR(S83)> @
CheckContainsText <$STR(S83)> ~
CheckContainsText <$STR(S83)> [
CheckContainsText <$STR(S83)> ]
CheckContainsText <$STR(S83)> <
CheckContainsText <$STR(S83)> >
CheckContainsText <$STR(S83)> {
CheckContainsText <$STR(S83)> }
CheckContainsText <$STR(S83)> 【
CheckContainsText <$STR(S83)> 】
CheckContainsText <$STR(S83)> PARAM
#Act
Mov S83
Messagebox 提示：请不要输入空格或非法字符!
GOTO @注册银行
Break


#IF
CheckStringlength <$STR(S83)> > 5
CheckStringlength <$STR(S83)> < 13
#ELSEACT
Mov S83
Messagebox 提示：请输入6-12位字母或数字!
GOTO @注册银行
Break


#IF
CheckTextList ..\..\..\..\天魔银行\账号目录.txt  <$STR(S83)>
#ACT
Mov S83
Messagebox 提示：您输入的账号已经存在!
GOTO @注册银行
BREAK


#IF
#ACT
GOTO @注册银行
BREAK




[@InPutString84]
#OR
CheckStringlength <$STR(S84)> < 1
CheckContainsText <$STR(S84)> @
CheckContainsText <$STR(S84)> ~
CheckContainsText <$STR(S84)> [
CheckContainsText <$STR(S84)> ]
CheckContainsText <$STR(S84)> <
CheckContainsText <$STR(S84)> >
CheckContainsText <$STR(S84)> {
CheckContainsText <$STR(S84)> }
CheckContainsText <$STR(S84)> 【
CheckContainsText <$STR(S84)> 】
CheckContainsText <$STR(S84)> PARAM
#Act
Mov S84
Messagebox 提示：请不要输入空格或非法字符!
GOTO @注册银行
Break


#IF
CheckStringlength <$STR(S84)> > 5
CheckStringlength <$STR(S84)> < 13
#ELSEACT
Mov S84
Messagebox 提示：请输入6-12位字母或数字!
GOTO @注册银行
Break


#IF
#ACT
GOTO @注册银行
BREAK








[@InPutString85]
#OR
CheckStringlength <$STR(S85)> < 1
#Act
Mov        S85
Messagebox        提示：请不要输入空格!
GOTO @注册银行
Break


#if
NOT EQUAL <$STR(S84)> <$STR(S85)>
#Act
Mov S85
Messagebox 提示：两次输入的密码不一致!
GOTO @注册银行
Break


#IF
#ACT
GOTO @注册银行
BREAK


[@InPutString86]
#OR
CheckStringlength <$STR(S86)> < 1
CheckContainsText <$STR(S86)> @
CheckContainsText <$STR(S86)> ~
CheckContainsText <$STR(S86)> [
CheckContainsText <$STR(S86)> ]
CheckContainsText <$STR(S86)> <
CheckContainsText <$STR(S86)> >
CheckContainsText <$STR(S86)> {
CheckContainsText <$STR(S86)> }
CheckContainsText <$STR(S86)> 【
CheckContainsText <$STR(S86)> 】
CheckContainsText <$STR(S86)> PARAM
#Act
Mov S86
Messagebox 提示：请不要输入空格或非法字符!
GOTO @注册银行
Break


#if
EQUAL <$STR(S84)> <$STR(S86)>
#Act
Mov S86
Messagebox 提示：二级密码不能和登录密码相同!
GOTO @注册银行
Break


#IF
CheckStringlength <$STR(S86)> > 5
CheckStringlength <$STR(S86)> < 13
#ELSEACT
Mov S86
Messagebox 提示：请输入6-12位字母或数字!
GOTO @注册银行
Break


#IF
#ACT
GOTO @注册银行
BREAK
;===========================登录银行账户===========================


[@登录银行]
#IF
#ACT
OPENMERCHANTBIGDLG 55 20 1 4 40 -40 1 426 20


#SAY
\ \ \


<>                 <银行账号：/FCOLOR=243> <$STR(S81)>  <请输入银行账号/@@InPutString81>\　 \
<>                 <银行密码：/FCOLOR=243> <$STR(S82)>  <请输入银行密码/@@InPutString82>\　 \
<>                 <二级密保：/FCOLOR=243> <$STR(S87)>  <请输入二级密保/@@InPutString87>\　 \
<>                                <登录银行/@登录银行1>


[@InPutString81]
#OR
CheckStringlength <$STR(S81)> < 1
#Act
Mov S81
Messagebox 提示：请不要输入空格!
GOTO @登录银行
Break


#IF
#ACT
GOTO @登录银行
BREAK


[@InPutString82]
#OR
CheckStringlength <$STR(S82)> < 1
#Act
Mov S82
Messagebox 提示：请不要输入空格!
GOTO @登录银行
Break


#IF
#ACT
GOTO @登录银行
BREAK


[@InPutString87]
#OR
CheckStringlength <$STR(S87)> < 1
#Act
Mov S87
Messagebox 提示：请不要输入空格!
GOTO @登录银行
Break


#IF
#ACT
GOTO @登录银行
BREAK


[@登录银行1]
#IF
CheckTextList ..\..\..\..\天魔银行\账号密码.txt 账号<$STR(S81)>:密码<$STR(S82)>
CheckTextList ..\..\..\..\天魔银行\账号密保.txt 账号<$STR(S81)>:密保<$STR(S87)>
#ACT
GOTO @人物银行
Break
#ELSEACT
MESSAGEBOX  [提示]：您输入的资料不正确，请重新输入！！


;===========================银行账户余额===========================


[@人物银行]
#IF
CheckTextList ..\..\..\..\天魔银行\账号密码.txt 账号<$STR(S81)>:密码<$STR(S82)>
#ACT
GetListString ..\..\..\..\天魔银行\银行账号\<$STR(S81)>.txt 0 <$STR(N$RMB记录)>


#IF
#ACT
OPENMERCHANTBIGDLG 55 20 1 4 40 -40 1 426 20


#SAY
\ \ \
< >    <在这里您可以把四象之力进行储存，储存的四象之力可以在任何区使用。/FCOLOR=154>\
< >    <凭独立账号密码,跨区存取四象之力（与角色账号无关）防止被盗号。/FCOLOR=154>\
< >  <重要提示：请牢记设置的用户名、密码、二级密码，不要设置过于简单！/FCOLOR=249>\
< >  <重要提示：一次性最多取5w材料 如果取多了材料丢失后果自负！/FCOLOR=250>\ \
<>   　　<用 户 名：/FCOLOR=251> <$STR(S81)>　　  　 <账户余额：/FCOLOR=251> <$STR(N$RMB记录)>\   \
<>               <我要存款/@@InPutInteger23>                    <我要取款/@@InPutInteger24>      


[@InPutInteger23]
#IF
small N23 1
#ACT
MOV N23 0
MESSAGEBOX \[提示]：最低存入：1个四象之力\\
BREAK


#IF
CheckTextList ..\..\..\..\天魔银行\账号密码.txt 账号<$STR(S81)>:密码<$STR(S82)>
#ACT




#IF
CHECKITEM 四象之力 <$STR(N23)>
#ACT
take 四象之力 <$STR(N23)>
GetListString ..\..\..\..\天魔银行\银行账号\<$STR(S81)>.txt 0 <$STR(N$RMB记录)>
GetListString ..\..\..\..\天魔银行\一共存款.txt 0 <$STR(N$RMB一共)>
INC N$RMB记录 <$str(N23)>
CLEARNAMELIST ..\..\..\..\天魔银行\银行账号\<$STR(S81)>.txt
AddTextListEX ..\..\..\..\天魔银行\银行账号\<$STR(S81)>.txt <$str(N$RMB记录)> 0
MESSAGEBOX [提示]：成功存入<$STR(N23)>个四象之力。
GetListString ..\..\..\..\天魔银行\银行账号\<$STR(S81)>.txt 0 <$STR(N$RMB记录)>
AddTextListEX ..\..\..\..\天魔银行\银行流水\<$STR(S81)>.txt 存入时间：<$DATETIME>‖区名：<$SERVERNAME>‖帐号：<$USERID>‖角色：<$USERNAME>‖存入四象之力：<$STR(N23)>‖剩余四象之力：<$STR(N$RMB记录)> 0
INC N$RMB一共 <$str(N23)>
CLEARNAMELIST ..\..\..\..\天魔银行\一共存款.txt
AddTextListEX ..\..\..\..\天魔银行\一共存款.txt <$str(N$RMB一共)> 0
MOV N23 0
GOTO @人物银行
#ELSEACT
MESSAGEBOX \[提示]：您的四象之力不足<$STR(N23)>个。
MOV N23 0
MOV N$RMB存入 0
BREAK




[@InPutInteger24]
#IF
small N24 1
#ACT
MOV N24 0
MESSAGEBOX [提示]：最少取出：1个四象之力。
BREAK


#IF
CheckTextList ..\..\..\..\天魔银行\账号密码.txt 账号<$STR(S81)>:密码<$STR(S82)>
#ACT
GetListString ..\..\..\..\天魔银行\银行账号\<$STR(S81)>.txt 0 <$STR(N$RMB记录)>
GetListString ..\..\..\..\天魔银行\一共存款.txt 0 <$STR(N$RMB一共)>
MOV U38 <$STR(N$RMB记录)>


#or
large U38 <$STR(N24)>
EQUAL U38 <$STR(N24)>
#ACT
GetListString ..\..\..\..\天魔银行\银行账号\<$STR(S81)>.txt 0 <$STR(N$RMB记录)>
GetListString ..\..\..\..\天魔银行\一共存款.txt 0 <$STR(N$RMB一共)>
DEC U38 <$STR(N24)>
CLEARNAMELIST ..\..\..\..\天魔银行\银行账号\<$STR(S81)>.txt
AddTextListEX ..\..\..\..\天魔银行\银行账号\<$STR(S81)>.txt <$str(U38)> 0
GIVE 四象之力 <$STR(N24)>
MESSAGEBOX [提示]：成功取出<$STR(N24)>个四象之力。
GetListString ..\..\..\..\天魔银行\银行账号\<$STR(S81)>.txt 0 <$STR(N$RMB记录)>
AddTextListEX ..\..\..\..\天魔银行\银行流水\<$STR(S81)>.txt 取出时间：<$DATETIME>‖区名：<$SERVERNAME>‖帐号：<$USERID>‖角色：<$USERNAME>‖取出四象之力：<$STR(N24)>‖剩余四象之力：<$STR(N$RMB记录)> 0
DEC N$RMB一共 <$str(N24)>
CLEARNAMELIST ..\..\..\..\天魔银行\一共存款.txt
AddTextListEX ..\..\..\..\天魔银行\一共存款.txt <$str(N$RMB一共)> 0
MOV U38 0
MOV N24 0
GOTO @人物银行
#ELSEACT
MESSAGEBOX [提示]：您的账户四象之力不足<$STR(N24)>个。
MOV U38 0
MOV N24 0
BREAK


[@银行流水]
#IF
#ACT
CLOSE
DELAYGOTO 200 @银行流水2


[@银行流水2]
#IF
#ACT
OPENMERCHANTBIGDLG 24 110 1 4 0 -80 1 888 3 1
MOV N$转区编号0 0
MOV N$转区编号1 1
MOV N$转区编号2 2
MOV N$转区编号3 3
MOV N$转区编号4 4
MOV N$转区编号5 5
MOV N$转区编号6 6
MOV N$转区编号7 7
MOV N$转区编号8 8
MOV N$转区编号9 9
MOV N$转区编号10 10
MOV N$转区编号11 11
MOV N$转区编号12 12
MOV N$转区编号13 13
MOV N$转区编号14 14
MOV N$转区编号15 15
MOV N$转区编号16 16
MOV N$转区编号17 17
MOV N$转区编号18 18
MOV N$转区编号19 19
GOTO @流水界面


[@流水上一页]
#IF
LARGE N$转区编号0 19
#ACT
DEC N$转区编号0 20
DEC N$转区编号1 20
DEC N$转区编号2 20
DEC N$转区编号3 20
DEC N$转区编号4 20
DEC N$转区编号5 20
DEC N$转区编号6 20
DEC N$转区编号7 20
DEC N$转区编号8 20
DEC N$转区编号9 20
DEC N$转区编号10 20
DEC N$转区编号11 20
DEC N$转区编号12 20
DEC N$转区编号13 20
DEC N$转区编号14 20
DEC N$转区编号15 20
DEC N$转区编号16 20
DEC N$转区编号17 20
DEC N$转区编号18 20
DEC N$转区编号19 20
GOTO @流水界面


[@流水下一页]
#IF
SMALL N$转区编号19 90
#ACT
INC N$转区编号0 20
INC N$转区编号1 20
INC N$转区编号2 20
INC N$转区编号3 20
INC N$转区编号4 20
INC N$转区编号5 20
INC N$转区编号6 20
INC N$转区编号7 20
INC N$转区编号8 20
INC N$转区编号9 20
INC N$转区编号10 20
INC N$转区编号11 20
INC N$转区编号12 20
INC N$转区编号13 20
INC N$转区编号14 20
INC N$转区编号15 20
INC N$转区编号16 20
INC N$转区编号17 20
INC N$转区编号18 20
INC N$转区编号19 20
GOTO @流水界面
#ELSEACT
MESSAGEBOX [提示：]当前只支持查看最近100条银行流水！


[@流水界面]
#ACT
GetListString ..\..\..\..\天魔银行\银行流水\<$STR(S21)>.txt <$STR(N$转区编号0)> S$流水行数0
GetListString ..\..\..\..\天魔银行\银行流水\<$STR(S21)>.txt <$STR(N$转区编号1)> S$流水行数1
GetListString ..\..\..\..\天魔银行\银行流水\<$STR(S21)>.txt <$STR(N$转区编号2)> S$流水行数2
GetListString ..\..\..\..\天魔银行\银行流水\<$STR(S21)>.txt <$STR(N$转区编号3)> S$流水行数3
GetListString ..\..\..\..\天魔银行\银行流水\<$STR(S21)>.txt <$STR(N$转区编号4)> S$流水行数4
GetListString ..\..\..\..\天魔银行\银行流水\<$STR(S21)>.txt <$STR(N$转区编号5)> S$流水行数5
GetListString ..\..\..\..\天魔银行\银行流水\<$STR(S21)>.txt <$STR(N$转区编号6)> S$流水行数6
GetListString ..\..\..\..\天魔银行\银行流水\<$STR(S21)>.txt <$STR(N$转区编号7)> S$流水行数7
GetListString ..\..\..\..\天魔银行\银行流水\<$STR(S21)>.txt <$STR(N$转区编号8)> S$流水行数8
GetListString ..\..\..\..\天魔银行\银行流水\<$STR(S21)>.txt <$STR(N$转区编号9)> S$流水行数9
GetListString ..\..\..\..\天魔银行\银行流水\<$STR(S21)>.txt <$STR(N$转区编号10)> S$流水行数10
GetListString ..\..\..\..\天魔银行\银行流水\<$STR(S21)>.txt <$STR(N$转区编号11)> S$流水行数11
GetListString ..\..\..\..\天魔银行\银行流水\<$STR(S21)>.txt <$STR(N$转区编号12)> S$流水行数12
GetListString ..\..\..\..\天魔银行\银行流水\<$STR(S21)>.txt <$STR(N$转区编号13)> S$流水行数13
GetListString ..\..\..\..\天魔银行\银行流水\<$STR(S21)>.txt <$STR(N$转区编号14)> S$流水行数14
GetListString ..\..\..\..\天魔银行\银行流水\<$STR(S21)>.txt <$STR(N$转区编号15)> S$流水行数15
GetListString ..\..\..\..\天魔银行\银行流水\<$STR(S21)>.txt <$STR(N$转区编号16)> S$流水行数16
GetListString ..\..\..\..\天魔银行\银行流水\<$STR(S21)>.txt <$STR(N$转区编号17)> S$流水行数17
GetListString ..\..\..\..\天魔银行\银行流水\<$STR(S21)>.txt <$STR(N$转区编号18)> S$流水行数18
GetListString ..\..\..\..\天魔银行\银行流水\<$STR(S21)>.txt <$STR(N$转区编号19)> S$流水行数19
#SAY
\　\　\
\ <$STR(N$转区编号0)>.<$STR(S$流水行数0)>\
\ <$STR(N$转区编号1)>.<$STR(S$流水行数1)>\
\ <$STR(N$转区编号2)>.<$STR(S$流水行数2)>\
\ <$STR(N$转区编号3)>.<$STR(S$流水行数3)>\
\ <$STR(N$转区编号4)>.<$STR(S$流水行数4)>\
\ <====================================================================================================================================================/FCOLOR=12>
\ <$STR(N$转区编号5)>.<$STR(S$流水行数5)>\
\ <$STR(N$转区编号6)>.<$STR(S$流水行数6)>\
\ <$STR(N$转区编号7)>.<$STR(S$流水行数7)>\
\ <$STR(N$转区编号8)>.<$STR(S$流水行数8)>\
\ <$STR(N$转区编号9)>.<$STR(S$流水行数9)>\
\ <====================================================================================================================================================/FCOLOR=12>
\ <$STR(N$转区编号10)>.<$STR(S$流水行数10)>\
\ <$STR(N$转区编号11)>.<$STR(S$流水行数11)>\
\ <$STR(N$转区编号12)>.<$STR(S$流水行数12)>\
\ <$STR(N$转区编号13)>.<$STR(S$流水行数13)>\
\ <$STR(N$转区编号14)>.<$STR(S$流水行数14)>\
\ <====================================================================================================================================================/FCOLOR=12>
\ <$STR(N$转区编号15)>.<$STR(S$流水行数15)>\
\ <$STR(N$转区编号16)>.<$STR(S$流水行数16)>\
\ <$STR(N$转区编号17)>.<$STR(S$流水行数17)>\
\ <$STR(N$转区编号18)>.<$STR(S$流水行数18)>\
\ <$STR(N$转区编号19)>.<$STR(S$流水行数19)>\
\ <====================================================================================================================================================/FCOLOR=12>\
\                                        <【查看上一页】/@流水上一页>                                   <【查看下一页】/@流水下一页>     \